Starworshipperの裁縫箱



  • 学んだり、自分なりに思いついたことをひとくちメモしていきます。
    環境はWin10です。PCのスペックは🍠です。

    ふんだんに間違っている可能性などがあるので、
    よろしくない場合は指摘して頂けると幸いです。

    【コミュニティから得たものはコミュニティに還元を】
    にリスペクトを込めて。

    (自分のメモに還元の価値があるかはまた別問題ですが!😂)


    ・マクロは自己責任で
    私が使っているものなので、家ごと吹っ飛んだりすることはないと確約しますが、
    データが吹っ飛んでも責任は持ちません。

    ・なんで裁縫箱なのか:
    おばあちゃんの裁縫箱って、得体のしれない予備ボタンの山の他に、切手や、ヘアピンや、何故か1ペニー硬貨とか入ってたりしません?
    ここのメモも、ごった煮の道具の入ったクッキー缶みたいなものなので、
    ピッタリかなと思ったのです。


    memo markdown
    https://commonmark.org/help/
    ~~打ち消し _B __伊
    #は6個まで #5以降は小文字
    said in メモ:



  • 貼る理由もないくらいシンプルなやつですが、マクロってまずはこういうことですよねという。

    ワンボタンごとに10回ブラー掛けます。
    IFreezeをつけたして、10ミリオンなハイポリでもそれなりに素早く、ボケマスクを作れますってところだけがミソです。

    よくマスクをぼかすのにボタンを連打してるので、記録してみました。
    ブラー100でドカンとぼかしたあと、マスクのブラーの値を戻しています。

    //ZBRUSH MACRO - Recorded in ZBrush version 2020
    [IButton,???,"10Times mask bluring",
    	[IShowActions,0]
    	[IConfig,2020]
    	
    	[VarDef, qwMBS,0]
    	[VarSet,qwMBS, [IGet,Preferences:Transpose:Mask Blur Strength]]
    	
    	[MergeUndo]
    	[IFreeze, //一連の処理をUIの処理なしで動作を行い、高速化する
    		[ISet,Preferences:Transpose:Mask Blur Strength,100]
    		[Loop,10,
    			[IPress,Tool:Masking:BlurMask]
    
    		]
    		[ISet,Preferences:Transpose:Mask Blur Strength,qwMBS]
    	]
    ]
    
    

    せめてテキストファイルくらい貼れると良いのですが・・・。



  • 危険な香り? 好きな場所に好きなマクロを配置しちゃう!

    例えば、UVマスターしたあとに、平面化ではなく、モーフUVして具合を確かめることがよくあるので、
    どうせならそこにボタンがあったら良いなと思い、追加したりしてます。
    (動きでモデルのどこがどこに展開されたか視認しやすい!)

    こんなことしていいか怪しいので、ちょっと怖い所があります。

    IButtonの???と記録されているとこに、そこまでのパスとボタン名を書いただけです。
    ??? -> "Zplugin:UV Master:My-morphUV"
    これで、「Zplugin」のなかの「UV Master」に「My-morphUV」というボタンが追加されます。

    0_1586017833976_コメント 2020-04-05 012926.png

    //ZBRUSH MACRO - Recorded in ZBrush version 2020
    [IButton,"Zplugin:UV Master:My-morphUV","Just Toggle MorphUV.",
    	[IShowActions,0]
    	[IConfig,2020]
    	[IToggle,Tool:UV Map:Morph UV]
    ]
    
    [ISlider,"Zplugin:UV Master:R-Mrph UV Timer", 4,0.1,0,10,"Push Value to Preference: Morph UV Timer",    //デフォルト, 刻み幅, Min, Max ,ポップアップテキスト, 実行
    [VarDef,qwMUT,[IGet, "Zplugin:UV Master:R-Mrph UV Timer"] ]
    [VarSet,qwMUT,[IGet, "Zplugin:UV Master:R-Mrph UV Timer"] ]
    
    //[Note, qwMUT]
    
    [ISet,"Preferences:Interface:Morph UV Timer", qwMUT ]
    ]
    
    

    追記:2020-04-13:モーフUVタイマーのスライダーを強引にUVマスターにねじ込む記述を追加。



  • ZBrush2020.1.1+ Sketchfab Exporter 4.0における挙動について。

    今現在、2020/04/05において、
    ZBrush2020.1.1+ Sketchfab Exporter 4.0を使っていると、
    「サブツール内のフォルダ機能」を使用した際、エラーが出て停止します。

    【環境設定→インターフェース→サブツールフォルダの表示】
    をオフにして、
    フォルダ機能を一時的に無効にすると、Exporterがきちんと動作します。

    ちなみに、一度Exporterがエラーを吐いたら、その後はうんともすんとも動かなくなってしまうので、
    ファイルをクイックセーブでもして、ZBrushを再起動すると良いです。


    毎度これを忘れて、そのたびにZBrushを再起動しなくてはならなくなり、
    地味にキレそうだったので、

    //ZBRUSH MACRO - Recorded in ZBrush version 2020
    [IButton, Zplugin:Sketchfab Uploader V4.0: FolderToggle ,"Folder function toggle",
    [IShowActions,0]
    [IConfig,2020]
    [IToggle,Preferences:Interface:Show Subtools Folders]
    ]
    

    こんなマクロを作って、ボタンを一番下に添加してます。



  • 唾を付けた場所から、どこまでも広がっていくトポロジカルマスキング。

    モデルは、1つのサブツールにまとめたデモソルジャー。

    トランスポーズマスターを使っている時とかに便利だと思います :)
    (PG分けや非表示領域拡張とかと組み合わせて、痒いところをかいてます。)

    黒く唾を付けたら、マスク領域反転して、
    マスク調整をこんな感じにして、
    適用を連打するだけです。
    0_1586020265059_トポロジカルマスキング.png

    ギズモのトポロジカルマスキングが意外とピーキーで、
    ちょっと辛いなと思った私のような人に向け?

    Coreもマスク調整があるなら出来るはず。



  • 現在のサブツールのそれぞれのSdivの状態で、
    今画面に表示されてる状態は、一体何ポリカウントあるのかカウントするマクロ。

    Sketchfabにアップロードする時などに--------------------
    Sketchfab Exporterには、現在のSdivをSketchfabにアップロードするという機能があります。
    ファイルサイズぎりぎりのハイポリを上げたい時に、
    あれをSdiv.1に、それをSdiv.2に、これをSdiv.3に・・・、
    と選んだ時に、「で、結局今画面に写っているのは何ポリ!? 
    Total Points countは、最大Sdivのカウントしか出してくれないし・・・」
    となりましたので、電卓を叩く代わりに記録したものです。

    ローポリ数の計算-----------
    SDivを掛けて、ポリペイントなどをしながらローポリを作成している時などに、
    全てをSdiv1に合わせることで、
    自分のツールが、実際何頂点の、何ポリ数のローポリなのか
    計るのにも使えると思いますです。

    もっと良い方法があったらぜひご教示お願い致します!

    //ZBRUSH MACRO - Recorded in ZBrush version 2020
    [IButton,???,"Press to run this macro. Macros can be aborted by pressing the ëescí key.",
    
    	//qwSTN  sub tool number
    	//qwFFLUSH   string for output   [StrMerge,"Subtool Numbers:",qwSTN, " FFLUSH"]
    	//qwPoints  get active points count 		[Mesh3DGet, 0]  1 is face
    	[IShowActions,0]
    	[IConfig,2020]
    	[VarDef, qwPoints, "honk"]
    	[VarDef, qwTotalPoints, 0]
    	[VarDef, qwFaceCount, "honk"]
    	[VarDef, qwTotalFaceCount, 0]
    
     	[VarDef, qwSTN, [SubToolGetCount]]
     	
    	[VarSet, qwPoints, "honk"]
    	[VarSet, qwTotalPoints, 0]
    	[VarSet, qwFaceCount, "honk"]
    	[VarSet, qwTotalFaceCount, 0]
     	[VarSet, qwSTN, [SubToolGetCount]]
     	
     	//[VarSet, FFLUSH, [StrMerge,"Subtool Numbers:",qwSTN]]
     	[VarSet, qwFFLUSH, [StrMerge,"Subtool Numbers:",qwSTN  ]]
     	
    	[NoteBar, qwFFLUSH ] //ステータスバー(上部)に文字表示
    	[Note, qwFFLUSH ]
    
    //test
    //	[Mesh3DGet,0,,, qwPoints ] // 0= points   1=faces
    //	[VarSet, qwFFLUSH, [StrMerge,"Points  Numbers:",qwPoints  ]]
    //	[Note,  qwFFLUSH]
    
    //active points count
    	[Loop, qwSTN , 
    	// 上からn番目のツールを選択した状態にする
    		[SubToolSelect, [Val, n]]
    		[Mesh3DGet,0,,, qwPoints ] 
    		[Mesh3DGet,1,,, qwFaceCount ] 
    		[VarSet, qwTotalPoints , qwTotalPoints+qwPoints ]
    		[VarSet, qwTotalFaceCount , qwTotalFaceCount+qwFaceCount ]
    		,
    		n
    	]
    	
    	[VarSet, qwFFLUSH, [StrMerge,"Total Current SDiv Points  Counts: ",qwTotalPoints ,
    	"\n\n",
    	"Total Current SDiv Faces Counts: ",qwTotalFaceCount ,"\n(Squares and Tris.)"
    	  ]]
    	[Note,  qwFFLUSH]
    ] //End of IButton main
    
    

    vardefとversetが変な感じになっているのは、ボタン押すたびに変数揮発するかと思いきや、意外としぶとく生き残っているので、この仕様。
    setを消して起動すると、ボタンを押すたびにどんどん加算されていく、揮発しない!honk!

    (変数のネーミング :) )



  • 60秒で作るダウンタウンのミニチュアのチュートリアルでございます。
    60秒なりのクオリティですが、
    フォトバッシュ用の、遠景の水増しプロップくらいには使えるのではないでしょうか。

    https://kizakiaoi.wordpress.com/2020/01/09/zbrush_dynamesh/
    「Dynameshのご先祖様」のところを読んで、初めてこの機能が目に写り、色々触った次第の結果です🤡

    (動画作ったあとに、Paintブラシにテクスチャがハマってて、
    実はスポットライトを盛大に失敗してることに気づきましたが、それっぽいのでそのままです 😂😂😂)
    (ライティングは、右からのオレンジの強い光+上からほんの少し日、というライトキャップを作り、
    印象的な左への影をメインライトで醸しています。 + AO)

    屋根のポリゴンを選択して、アンテナや貯水塔、排気口、室外機などのプロップを、ナノメッシュでまぶしたりすると、
    更にフィーリング良くなると思います。
    室外機は、側面にまぶしても効果的かもしれませんね。



  • SnapCurveBrushで作る、厚みを持ったスカート、カーテン素体。
    最初から厚みがあって、形状として安定してる所がミソだと思います。

    厚みがいらない場合は、ポリグループ選択すれば、欲しい面だけ選んで、厚みを消すことも可能です。

    SnapCurveBrushの貫通性を逆手に取った感じです。
    円柱ではなく、あえて球をベースにカーブを入れることで、
    シワの上側と下側で円周が変わるので、更にそれっぽく見えると思います。

    球に沿って描くだけなので、風でなびいたスカートのベースなども、
    球をいびつに用意することにより、簡単に実装できると思います。

    SnapCurveBrushはカーブを掛けば書いただけつながっていくので、ベースのメッシュを動かしながら何度もカーブを描くことで、
    手数を増やせば、複雑にはためいた布もいけると思います。

    追記:2020/08/21
    2021のクロスシミュがあるから、こんな小技いらなくなったね!



  • PureRefは便利というお話

    ZBrushそのものとは関係ないですが、ZBrushを使うに当たって、
    これがあるとクリエイティブが捗ると思ったのでメモ。

    🎨PureRef🎨
    https://www.pureref.com/
    昨今の作品作りにとって、参考資料集めはとても大切なものと言われています。[誰が?][自己研究][要出典]🤣
    そんなごちゃごちゃになりがちな資料を、
    スクラップブックのように、好きな順番で好きなように並べて表示する事ができるソフト。

    0_1587716622184_コメント 2020-04-23 142703.png
    こんな感じで、好きな画像をピタピタと黒窓に貼って、それを最前面に表示し、参考資料として表示できるのです。
    どうです?とんでもなく便利でしょう?😏
    私にとっては「BC、AD」の如く、「PureRef前、PureRef後」をはっきり感じるほど、創作に影響しております。
    資料集めが苦にならなくなるというアドバンテージは、とてつもなく大きいです!🎃

    例えば、Pinterestでざっくり大きな資料を集めて、そこからさらに洗練したチョイスをこれに挟んだりすると、
    創作欲を刺激するスクラップが作りやすいと思います。


    (有名すぎて知らん人がいないんではないか言う話ですが、😎
    少なくとも、Centralで検索掛けたらまだ記事に登ってなかったので、この期にご紹介!

    他にもこの手のリファレンスソフトは色々有るので、
    自分にピッタリあった使い勝手のものを探すのもまたオツかと思います)



  • メモ

    GoZがおかしい時

    "Unable To Open File~"とか言われて開けないときは、
    C:\Program Files\Pixologic\ZBrush xxxxx\Troubleshoot Helpに、
    GoZのインストーラが入っている。

    新しいZBrushをクリーンインストールして、古い方をアンインストールした時などに、
    GoZを一緒に消してしまう可能性🤣

    こちらの記事より:
    http://lightbreeze.asablo.jp/blog/2018/05/02/8840286



  • 正面をマスク

    ポリグループに、正面をグループ化という便利な機能がある。
    ビューから見た正面をポリグループにしてくれる。

    マスクでこれをやりたい場合、 ドラフト→指定 してから ドラフトから を押すと、
    似たような挙動でマスクしてくれるようである。
    (ドラフト角などを微調整のこと)

    0_1588644179959_upload-a4c239f4-5a6e-48a0-a2a8-70bbc7b5bf9e

    ドラフトの機能なので、アンダーカットの処理などが、若干違う挙動になっている点は注意。



  • ビューカメラのバレルロール

    Ctrl押しながら、Gizmoのこれをクリック&ドラッグすると、ギズモを基点に、ビューカメラが回転する。
    (トランスポーズラインの白丸Ctrlドラッグと同じ挙動ですね)

    0_1590234411271_upload-bd431548-2dfd-4058-89b6-0d886d1e8bad

    または、ビューポート上で、
    「Shift押し込み-> 右クリック押し込み-> Shift離す-> 右押し込んだままドラッグ」
    でもビューカメラが回転します。



  • 擬似強烈ライティング

    「BPRフィルタ→ ペイント(グローとか置き換え、お好み :))」
    をノーマルマスクを用いて掛けると、こんな感じでカラーライティングを簡単に付け足せます。

    0_1590504698636_upload-73ef28ad-7eea-4fe8-a6a9-e1cfb59e31b1
    80’s Neon Style💾📺😎

    ライトのライティングよりも、マスクやフレネル、AOなどでコントロールが効くので、
    けれんみのあるハイライトやリムライトなどの仕上げにどうでしょう。
    0_1590505200801_upload-19f4715e-4d1c-444c-951a-d635576ac04e



  • ドロー→ カメラ→ アンドゥ

    細かい作業してたら、メッシュの外をドラッグしちゃって、カメラがズルっ!
    「だぁらっしゃぁ!もとのカメラアングル返せっ!」なんてときのボタンなのかなと思います。

    個人的には、指などを変形するとき、「トランスポーズ用真横アングル<—>マスキング用縦アングル」の行き来が大変に楽になるので、そんなときも使えるのかなぁと。🤔

    0_1590505653020_upload-8accb0dc-128e-4269-a8cd-072c198289aa



  • Win10での簡単スクリーンショット

    ちょっとZBrushから外れるトピックですが、
    フォーラムへの画像投稿がしやすくなるということで。😋

    Win+Shift+s
    で、注釈も簡単に入れられるトリミング型のスクリーンショットアプリが起動するのです。
    0_1590575883943_upload-4be2c556-8727-4f83-a33f-337e3ac70d41

    注釈を描いたら、スクリーンショッター上でCtrl+C押して、
    その後、フォーラムでCtrl+v。簡単にスクリーンショットを取り込めます。

    Purerefと組み合わせたあとに、pureref自体を「Win+Shift+s」してしまえば、
    複数のスクリーンショットの組み合わせがさらに簡単。📸
    マッハで起動し、用紙サイズなど気にせずペタペタ出来るので、メモレベルの編集には最適。

    0_1590576262776_upload-294de4f4-8225-415b-bd7c-d55c45494d8d

    そして余談、Win+.(ピリオド)で、絵文字一覧アプリが起動する。🎊



  • トランスポーズマスターの前に、非表示メッシュを表示してくれるボタン

    トランスポーズマスターには、
    「非表示ポリゴンがある状態で起動すると、エラー無しで起動したのち、
    確定時にトポロジー不整合エラーが出て水の泡になる」
    というファンシーな挙動があります。
    (一応、エラー起こしたサブツールだけ抽出して→obj書き出しして→最低Sdivにインポートして~
    で、リカバリ出来るかもしれませんが、どうでしょう🤔)

    ごきげんなポーズを取ったあとに、「さあ確定!→エラー!→💀💀💀 → Press F」
    を複数回やらかしたので、こんなボタンを作りました。
    🍥 私はこのボタンからしかトランスポーズマスターしません!

    //ZBRUSH MACRO - Recorded in ZBrush version 2020
    [IButton,???,"Press to run this macro. Macros can be aborted by pressing the ëescí key.",
    	[IShowActions,0]
    	[IConfig,2020]
    
    	[VarDef, qwVVV,""]
    	 [VarDef, qwSTN, [SubToolGetCount]]
    	 [VarSet, qwSTN, [SubToolGetCount]]
    
    	[VarSet, qwVVV,  [MessageYesNoCancel, "Recovery hidden to see?----  (no: Just run T-pose mesh)"]]
    
    	//(NO=0, YES=1 CANCEL=-1)(
    	 [If,  qwVVV== 1 //YES
    	 ,   // Then...
    	 	[IColorSet,36,252,35]
    
    	 	[IFReeze,
    	 		//[IPress,Zplugin:Clean Tool Master:SubTool Cleaning:Show Hidden]
    			[Loop, qwSTN ,
    				[SubToolSelect, [Val, n]]// 上からn番目のツールを選択した状態にする
    				[IPress,Tool:Visibility:ShowPt]
    				,
    				n
    			]
    		]
    		 [IPress,Zplugin:Transpose Master:TPoseMesh]
    
    	 ,   // Else...
    		[If,  qwVVV== 0 //NO
    		 ,   // Then...
    		 	[IColorSet,36,252,35]
    
    			[IPress,Zplugin:Transpose Master:TPoseMesh]
    		 ,   // Else... // -1 Cancel
    		  //何もしない
    		  	 		[Sleep, 100, [Note, "LButton pressed"], 4]
    
    		]
    
    	 ]
    
    
    ]
    
    

    更新:2020/06/10 verdefとsetを間違っていて、ZBrush起動後1回しか動作しなかったので修正



  • 透明編集をお好みカラーで

    「トランスフォーム→ 透明編集」のデフォルトカラーって、ポリペイントなしの場合、
    白に白基調で、ちょっと見にくかったりするときがありませんか?🤔

    「環境設定→ドロー」の赤丸部分で、自在に色を変えることが出来ます。

    0_1590578826725_upload-a60eae4e-bc8f-4c59-a29c-10eff7208356
    ライトシアン基調にして、「80’s SFのステータス表示」みたいな風合いにした例👾。個人的に見やすいと思うんだぜ?😎



  • ある文字列が含まれるサブツールのみの
    DynamicSDivをON,OFFするマクロ


    たくさんのサブツールに美しいダイナミックSDivを掛けると、モデリングするにはちょっくらモッサリ重くなりません?🧱🧱🧱
    それでいて、掛けたいサブツールと、掛けたくないサブツールがあり、
    モデリング時と、レンダーや試写の度に、ちまちま切り替えるのは面倒。
    さらには細かい所の切り替えを忘れたり・・・。🤐

    こちらは、
    「腕のサブツール --dns」(ダブルハイフンdns)みたいな感じでサフィックスが付いたサブツールのみ、
    ダイナミックSDivを切り替えるマクロ。

    作ってるときは、基本的にダイナミックはOFFで気持ちよくモデリング!
    すべてが終わり、レンダリングや試写のときにこのボタンをポチッと押すだけで、
    必要なサブツールだけがサラッと美しいDSdivをまとった状態になるという寸法のマクロ。
    出てきたダイアログのYesでON、NOでオフの切り替え。

    (本当は完全なサフィックス、プレフィックス制にしたかったけど、StrFindくらいしか扱えるスクリプトが思い浮かばなかったので、
    実のところは「なんたら --dnsなんたら」とかでも動いちゃうワイルドボンゴな仕様 :)
    しかも、[StrFind, “- -dns”,qwsubTName ] とハードコーディング。簡単に好きな文字列に直せるね!)

    (一つ一つDSDivの設定をすれば、こんな面倒なことしなくても、
    ただ全部オンオフするだけで良いんでしょうけど、DSDivって、設定しないサブツールのほうが多くありません?
    サブツール100個とかあると、設定が面倒になる😂🤔)

    //ZBRUSH MACRO - Recorded in ZBrush version 2020
    [IButton,???,"Press to run this macro. Macros can be aborted by pressing the ëescí key.",
    [IShowActions,0]
    [IConfig,2020]
    
    [VarDef, qwToggle,""]
    [VarDef,qwsubTName,""]//defines variable as empty string
    [VarDef,totalSubTools,""]//the total number of subtools
    [VarDef,activeSubT,""]//record the active subtool
    
    
    [VarSet, qwToggle,  [MessageYesNo, "SubtoolName--dns -----All DynamicSdiv? (Yes=ON, No=OFF)"]]
    	//(NO=0, YES=1 )(
    
    
    
    [VarSet,totalSubTools,[SubToolGetCount]]//the total number of subtools
    [VarSet,activeSubT,[SubToolGetActiveIndex]]//record the active subtool
    
    [If,activeSubT==0,[SubToolSelect,1]]//this stops an error if the top subtool is selected but hidden in the list
    [Loop,totalSubTools,  
    	[SubToolSelect,[Val,n]]//selects the subtool by number
    	[VarSet,qwsubTName,[IGetTitle,Tool:ItemInfo]]//gets the tool name
    	
    	[If, [StrFind, "--dns",qwsubTName ]==-1  //文字列がない場合 -1を返し、文字列があったら、何文字目にあったかを返す
    	 ,//then -1なので --dnsという文字列がない場合
    	 																					//[note, qwsubTName]//debug
    	,//else 文字列があったら
    		[IF, qwToggle==1
    		,//then
    			[IPress,Tool:Geometry:s.Dynamic]
    		,//else
    			[IUnPress,Tool:Geometry:s.Dynamic]
    		]
    	]  	
    ,n]
    
    ]//end of macro
    


  • SnakeHookと和解せよ

    方々で様々な方が口が酸っぱくなるほど言っていることなので、2000%今更な話なのですが、
    知らなかったそこの貴方へ。👉

    SnakeHookというブラシは、棘を立てるためだけにあると思っていると
    MOTTTAINAI!

    モデルが覆いかぶさるくらいの大きなブラシサイズでSnakeHookを扱うと、
    実は、よりダイナミックな挙動のMove系ブラシとして使えるのです。

    0_1592567617533_upload-bc2740f7-2672-439f-9432-00b24a67260f

    Moveというアクションだけでも、他にも一例として、
    ・Move
    ・MoveInfinite (2020の新機能を用いたブラシ)
    ・MoveElastic
    ・SnakeHook
    を始めとした、全く挙動の違う特徴的なMove系ブラシがありますので、
    知らなかった方は、これを機会に、Moveの際、Move一択になっていたフローを見直してみてはいかがでしょう?
    より心地よくMoveできるようになるかもしれませんよ?

    他にも有志の方がカスタムMoveブラシを公開していたりするので、
    そちらを利用してみるのも手でしょう。
    Moveというアクションは、ただ動かすだけなのに、とても奥が深いアクションなのです。



  • 現在のサブツールを選択されたマテリアルで塗りつぶすボタン

    ファイルネームは、「Fill Mat.txt」とかがそれっぽいボタンネームになるかと思います。
    要は、FillObjectのマテリアル限定版ボタン。
    ブラシのRGBやMのボタンをIF参照して、塗りつぶした後に元に戻してるだけです。
    地味に便利なのよ?自分だけ?😆

    //ZBRUSH MACRO - Recorded in ZBrush version 2020
    [IButton,???,"Fill Current subtool by the selected materials",
    	[IShowActions,0]
    	[IConfig,2020]
    
    	[If,  [IGet,Draw:Rgb]==1 //RGBオンなら
    	 ,   // Then...
    		[IPress,Draw:M]
    		[IPress,Color:FillObject]
    		[IPress,Draw:Rgb]
    													//[Note,"RGM ON"]//debug
    
    	 ,   // Else...
    	 	[If,  [IGet,Draw:M]==1 //Mオンなら
    	 	,
    			[IPress,Color:FillObject]
    													//[Note,"M ON"]//debug
    		,// else
    			[If,  [IGet,Draw:Mrgb]==1 //MRGBオンなら
    			,// Then
    				[IPress,Draw:M]
    				[IPress,Color:FillObject]
    				[IPress,Draw:Mrgb]
    
    			,//else 要はここに来るてことは、全部オフ
    				[IPress,Draw:M]
    				[IPress,Color:FillObject]
    				[IUnPress,Draw:M]
    														//	[Note,"RGM M OFF"]//debug
    			]
    		]
    	]
    
    ]
    
    


  • 全てのサブツールをミラーするマクロ

    [IPress,Tool:Deformation:Mirror]
    のところを、録画したマクロのボタンの名前で置き換えれば、
    全てのサブツールに何かを適用するマクロとして、これ以外にも何でも応用が効くと思います。

    //ZBRUSH MACRO - Recorded in ZBrush version 2020
    [IButton,???,"Press to run this macro. Macros can be aborted by pressing the ëescí key.",
    	[IShowActions,0]
    	[IConfig,2021]
    	
    	 [VarDef, qwSTN, [SubToolGetCount]]
    	 [VarSet, qwSTN, [SubToolGetCount]]
    
    	[IFreeze,//画面描画を停止して高速化するおまじない
    		[Loop, qwSTN , 
    			[SubToolSelect, [Val, n]]// 上からn番目のツールを選択した状態にする			
    			[IPress,Tool:Deformation:Mirror]
    			,
    			n
    		]
    	]
    	
    ]
    


Looks like your connection to Starworshipperの裁縫箱 was lost, please wait while we try to reconnect.